CAD Forum

KQuigley wrote: ↑Wed Oct 18, 2023 11:05 am
But where Creo is better is in surface validation. This is the area they are really bothered about as they need to sign off data for tooling and right now the validation tools in Solidworks just don't cut the mustard (compared to the ones in creo).
XNurbs doesn't really do validation, but GeometryWorks seems to, so I've pointed them to that as well.

Arthur NY wrote: ↑Wed Oct 18, 2023 7:31 pm @KQuigley When you say validate the surface, are they going down the route of looking at surface continuity, zebra stripes, curvature continuity? or is this analysis of CAD to mesh data?

gristle wrote: ↑Mon Oct 23, 2023 3:41 pm

KQuigley wrote: ↑Tue Oct 24, 2023 11:54 am Validating the surface for tooling - so looking at continuity, flow, divergence etc.



100% agree there. Zebra and curvature can be quite poor in SW, as the user has little control over the analysis mesh that SW generates.
I have a macro set up to dump out any selected faces/bodies into Rhino where it runs a zebra analysis using explicit mesh settings.
It also means you can use the global edge analysis tool in Rhino, which gives you G0/1/2 info, with tolerances etc.

gristle wrote: ↑Tue Oct 24, 2023 4:18 pm ...
Here's my vid on setting up a macro to send surfaces to Rhino. If it's just a few surfaces, they appear in Rhino with little delay. I have it set up so Rhino comes to the front as well, once the surface has been imported. You only need to change the zebra settings once per session (have not figured out how to control the zebra settings from the SW macro). You can also use the Rhino curvature analysis tools, except do so with the expectation that your SW surfaces are not going to look too flash This macro works with the Rhino evaluation install, so no commercial seat needed.

mgibeault wrote: ↑Fri Oct 27, 2023 1:45 pm For the mesh settings, to have a good evaluation, you could insert this script that works well for a document in inches:
-Properties Object RenderMeshSettings Object AdvancedOptions Angle 15 AspectRatio 0 Distance 0 Density 1 Grid 16 MaxEdgeLength 0.015 MinEdgeLength 0.005
Enter Enter Enter Enter

For a document in mm:
-Properties Object RenderMeshSettings Object AdvancedOptions Angle 15 AspectRatio 0 Distance 0 Density 1 Grid 16 MaxEdgeLength 0.15 MinEdgeLength 0.05
Enter Enter Enter Enter

gristle wrote: ↑Fri Oct 27, 2023 2:59 pm ...
I've had several issues trying to get this to run. At first, It would open Rhino, but then something changed somewhere on my system, and I had to have Rhino opened first before running. I'm a macro/API beginner!

mgibeault wrote: ↑Fri Oct 27, 2023 3:43 pm Would you mind showing the first lines of the macro? I might miss some.

gristle wrote: ↑Fri Oct 27, 2023 5:45 pm There is a link to a .txt file of the macro in the video description, have you had a look at that?
Also may be differences between needed versions of Rhino (6, 7, 8)?

gristle wrote: ↑Fri Oct 27, 2023 2:59 pm Good stuff, save having to enter settings each time you start a session. I tend to use edge-surf deviation setting quite a bit as well. 0.0001mm if its a few surfs on a handheld sized product.

I've had several issues trying to get this to run. At first, It would open Rhino, but then something changed somewhere on my system, and I had to have Rhino opened first before running. I'm a macro/API beginner!

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swModelDocExt As SldWorks.ModelDocExtension
Dim opt As Long
Dim lErrors As Long
Dim lWarnings As Long
Dim Units As SldWorks.UserUnit

Const fileName As String = "C:\temp\analysisSurfaces.STEP"

Dim Rhino As Object
Dim objRhinoScript As Object

Sub Main()
    On Error Resume Next
    
    ' Initialize SolidWorks
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swModelDocExt = swModel.Extension

    If swApp Is Nothing Then
        MsgBox "SolidWorks is not running.", vbExclamation
        Exit Sub
    End If
    
    ' Check if a document is open in SolidWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then
        MsgBox "No active document in SolidWorks.", vbExclamation
        Exit Sub
    End If
    
    ' Export selected surfaces from SolidWorks to Rhino
    If ExportSelectedToRhino() Then
        'MsgBox "Export to Rhino completed successfully.", vbInformation
    Else
        MsgBox "Failed to export to Rhino.", vbCritical
    End If
End Sub

Function ExportSelectedToRhino() As Boolean
    ' Save As STEP file
    If swModelDocExt.SaveAs2(fileName, 0, opt, Nothing, "", False, lErrors, lWarnings) Then
        Set Rhino = CreateObject("Rhino.Interface")
        If Rhino Is Nothing Then
            MsgBox "Failed to create Rhino object.", vbCritical
            ExportSelectedToRhino = False
            Exit Function
        End If
        
        Rhino.Visible = True
        Set objRhinoScript = Rhino.GetScriptObject
        If objRhinoScript Is Nothing Then
            MsgBox "Failed to get RhinoScript object.", vbCritical
            ExportSelectedToRhino = False
            Exit Function
        End If
        
        ' Execute Rhino commands to import STEP file and manipulate view
        With objRhinoScript
            .Command "_Cancel _Enter"
            .Command "_SelAll _Delete"
            .Command "_-Import " & fileName & " _EnterEnd"
            .Command "_SelAll _Zoom _Selected _SetMaximizedViewport Perspective"
            .Command "_-Zebra _SelNone"
        End With
        
        ' Set mesh settings based on document units
        Set Units = swModel.GetUserUnit(swLengthUnit)
        'Debug.Print "  Unit type as defined in swUserUnitsType_e: " & Units.SpecificUnitType
        
        If Units.SpecificUnitType = 3 Then
            ' Document in inches
            With objRhinoScript
                .Command "_-SelAll"
                .Command "_-Properties _Object _RenderMeshSettings _Object _AdvancedOptions " & _
                "Angle=15 AspectRatio=0 Distance=0 Density=1 Grid=16 MaxEdgeLength=0.015 MinEdgeLength=0.005 _Enter _Enter _Enter _Enter"
                .Command "_-Zebra _SelNone"
            End With
        ElseIf Units.SpecificUnitType = 0 Then
            ' Document in millimeters
            With objRhinoScript
                .Command "_-SelAll"
                .Command "_-Properties _Object _RenderMeshSettings _Object _AdvancedOptions " & _
                    "Angle=15 _Enter AspectRatio=0 Distance=0 Density=1 Grid=16 MaxEdgeLength=0.15 MinEdgeLength=0.05 _Enter _Enter _Enter _Enter"
                .Command "_-Zebra _SelNone"
            End With
        Else
            MsgBox "Document units not recognized.", vbCritical
            ExportSelectedToRhino = False
            Exit Function
        End If
        
        Rhino.BringToTop
        ExportSelectedToRhino = True
    Else
        MsgBox "Failed to save SolidWorks document as STEP file.", vbCritical
        ExportSelectedToRhino = False
    End If
End Function

Halasox wrote: ↑Mon Mar 11, 2024 11:35 am I cleaned up the code a bit as I had some errors due to the obsolete saveAs3!

Code: Select all

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swModelDocExt As SldWorks.ModelDocExtension
Dim opt As Long
Dim lErrors As Long
Dim lWarnings As Long
Dim Units As SldWorks.UserUnit

Const fileName As String = "C:\temp\analysisSurfaces.STEP"

Dim Rhino As Object
Dim objRhinoScript As Object

Sub Main()
    On Error Resume Next
    
    ' Initialize SolidWorks
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swModelDocExt = swModel.Extension

    If swApp Is Nothing Then
        MsgBox "SolidWorks is not running.", vbExclamation
        Exit Sub
    End If
    
    ' Check if a document is open in SolidWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then
        MsgBox "No active document in SolidWorks.", vbExclamation
        Exit Sub
    End If
    
    ' Export selected surfaces from SolidWorks to Rhino
    If ExportSelectedToRhino() Then
        'MsgBox "Export to Rhino completed successfully.", vbInformation
    Else
        MsgBox "Failed to export to Rhino.", vbCritical
    End If
End Sub

Function ExportSelectedToRhino() As Boolean
    ' Save As STEP file
    If swModelDocExt.SaveAs2(fileName, 0, opt, Nothing, "", False, lErrors, lWarnings) Then
        Set Rhino = CreateObject("Rhino.Interface")
        If Rhino Is Nothing Then
            MsgBox "Failed to create Rhino object.", vbCritical
            ExportSelectedToRhino = False
            Exit Function
        End If
        
        Rhino.Visible = True
        Set objRhinoScript = Rhino.GetScriptObject
        If objRhinoScript Is Nothing Then
            MsgBox "Failed to get RhinoScript object.", vbCritical
            ExportSelectedToRhino = False
            Exit Function
        End If
        
        ' Execute Rhino commands to import STEP file and manipulate view
        With objRhinoScript
            .Command "_Cancel _Enter"
            .Command "_SelAll _Delete"
            .Command "_-Import " & fileName & " _EnterEnd"
            .Command "_SelAll _Zoom _Selected _SetMaximizedViewport Perspective"
            .Command "_-Zebra _SelNone"
        End With
        
        ' Set mesh settings based on document units
        Set Units = swModel.GetUserUnit(swLengthUnit)
        'Debug.Print "  Unit type as defined in swUserUnitsType_e: " & Units.SpecificUnitType
        
        If Units.SpecificUnitType = 3 Then
            ' Document in inches
            With objRhinoScript
                .Command "_-SelAll"
                .Command "_-Properties _Object _RenderMeshSettings _Object _AdvancedOptions " & _
                "Angle=15 AspectRatio=0 Distance=0 Density=1 Grid=16 MaxEdgeLength=0.015 MinEdgeLength=0.005 _Enter _Enter _Enter _Enter"
                .Command "_-Zebra _SelNone"
            End With
        ElseIf Units.SpecificUnitType = 0 Then
            ' Document in millimeters
            With objRhinoScript
                .Command "_-SelAll"
                .Command "_-Properties _Object _RenderMeshSettings _Object _AdvancedOptions " & _
                    "Angle=15 _Enter AspectRatio=0 Distance=0 Density=1 Grid=16 MaxEdgeLength=0.15 MinEdgeLength=0.05 _Enter _Enter _Enter _Enter"
                .Command "_-Zebra _SelNone"
            End With
        Else
            MsgBox "Document units not recognized.", vbCritical
            ExportSelectedToRhino = False
            Exit Function
        End If
        
        Rhino.BringToTop
        ExportSelectedToRhino = True
    Else
        MsgBox "Failed to save SolidWorks document as STEP file.", vbCritical
        ExportSelectedToRhino = False
    End If
End Function