josh wrote: ↑Fri Dec 27, 2024 11:45 pm
I don't think it exists "in" anything. I think the Display3 wording may be a bit imprecise. I'm not entirely sure, but I think it should say "where you want to display this temporary body", not "where this temporary body exists". That's why
displaying the body in the assembly shows it in assembly coordinates, and why you can make it display in whatever document or component you want. It won't actually
exist "in" or really be "owned by" anything until you turn the temporary body into a feature.
I can't test this theory with certainty because it is not possible to call Display3 while passing reference to a top-level assembly, it must be a component. I also suspect that temporary bodies are created in application-level. Especially because
IModeler, the interface responsible for creating temporary bodies, is called from Sldworks, rather than from ModelDoc2. However, I found this
post in the old forum where Artem says that a temporary body must have a container, which is whatever part is open in edit mode (EditPart2) when the body is created. But what if no part is in edit mode? Does that mean that the assembly itself is the container? Or is it like you said - there is no container at all?
I created a sample assembly and a macro for testing these things. Attaching to this post. It is an assembly with 3 components. First has it's origin matching the assembly origin, while the other 2 are moved. The third one also has the body away from the origin.
Macro code:
Code: Select all
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swAssy As AssemblyDoc
Sub main()
Set swApp = Application.SldWorks
Set swAssy = swApp.ActiveDoc
Dim comp1 As Component2
Dim comp2 As Component2
Dim comp3 As Component2
Set comp1 = swAssy.GetComponentByName("Comp1-1")
Set comp2 = swAssy.GetComponentByName("Comp2-1")
Set comp3 = swAssy.GetComponentByName("Comp3-1")
Dim components As New Collection
components.Add comp1
components.Add comp2
components.Add comp3
Dim tempBodies As Collection
Set tempBodies = CreateTempBodies(components)
DisplayBodies comp1, tempBodies
Debug.Print tempBodies(2).GetMassProperties(1000)(0)
Stop
End Sub
Function CreateTempBodies(components As Collection) As Collection
Set CreateTempBodies = New Collection
Dim component As Component2
For Each component In components
Dim bodies As Variant
Dim bodiesInfo As swBodyInfo_e
bodies = component.GetBodies3(swBodyType_e.swSolidBody, bodiesInfo)
Dim body As Body2
Dim i As Integer
For i = 0 To UBound(bodies)
Dim tempBody As Body2
Set tempBody = bodies(i).Copy2(False)
MoveBody component, tempBody
CreateTempBodies.Add tempBody
Next
Next
End Function
Sub MoveBody(component As Component2, body As Body2)
Dim compTransform As MathTransform
Set compTransform = component.Transform2
body.ApplyTransform compTransform
End Sub
Sub DisplayBodies(component As Component2, bodies As Collection)
Dim body As Body2
Dim i As Integer
For i = 1 To bodies.Count
Set body = bodies(i)
body.Display3 component, RGB(255, 0, 0), 1
Next
End Sub
Notice that when temporary bodies are created, they have to be moved in order to appear in correct positions (overlap the original bodies). Running this macro should give this:
However, if you comment out "MoveBody component, tempBody", then the temporary bodies end up at the assembly/first component origin:
This seems to imply that they are created using assembly coordinate system - meaning, the assembly is the container.
However, if you change "DisplayBodies comp1, tempBodies" to "DisplayBodies comp2, tempBodies", meaning that the graphics are hosted by the component that has a different origin, you get this:
It almost feels as if temporary bodies really do not exist until you call Display3 on them, which truly creates them in the model space, using the coordinates of whatever component you passed into Display3. However, applying transform prior to calling Display3 still moves them, which implies the opposite - they do exist somewhere.
Also, if after running this macro, you open Comp1 (which was passed to Display3), the temporary bodies are not visible there. Which implies that temporary body graphics are still hosted by the assembly..? This is really strange.
I also tried what Artem suggested: enter Edit Component mode in any of the components before calling this macro. It seems that in this case, nothing changes, temporary bodies do not change their positions, even if the edited component has it's origin off the assembly origin.
And if you open that component document separately (or any others), temporary bodies are not visible there. So again, this seems to imply that Edit Component does not change anything.
I also added a line at the end of the main method that prints the X coordinate of the temporary body created from Comp2. This coordinate (-0,465) matches what SW Mass Properties dialog shows in the assembly, which further seems to imply that temporary body container is the assembly.
Now, the weirdest thing... If you again change into "DisplayBodies comp2, tempBodies", which makes temporary bodies appear offset... GetMassProperties still reports X coordinate as (-0,465) !!!
This seems to imply that temporary body graphics and actual position are completely detached from one another. It appears that temporary body is hosted by the assembly and works in it's coordinate system, but it's graphics must be hosted by some specific component, using it's coordinate system... And yet opening that component separately shows that temporary body graphics are not there, which would imply that these graphics are also hosted in the assembly, at least in some sense..?
Now you can see why I'm so confused
If anyone can explain what is going on here, I'd really appreciate it...
P.S. I just realized I have mis-interpreted what Artem meant there in that post, that Edit Component only matters for CreateFeatureFromBody3, which makes sense. So please disregard my comments about running Copy2 while in component edit mode. The other oddities remain though.